' <summary>
' Make a global parameter to be driven by the value of a dimension.
' </summary>
' <param name="document">Revit project document containing the global parameter and dimension elements.</param>
' <param name="gpid">ElementId of a global parameter.</param>
' <param name="dimid">ElementId of a dimension element.</param>
Public Function AssignDrivingDimension(document As Document, gpid As ElementId, dimid As ElementId) As Boolean
    ' we expect to find the global parameter in the document
    Dim gp As GlobalParameter = TryCast(document.GetElement(gpid), GlobalParameter)
    If gp Is Nothing Then
        Return False
    End If

    ' we expect to find the given dimension in the document
    Dim [dim] As Dimension = TryCast(document.GetElement(dimid), Dimension)
    If [dim] Is Nothing Then
        Return False
    End If

    ' not every global parameter can label
    ' and not every dimension can be labeled
    If Not gp.CanLabelDimension(dimid) Then
        Return False
    End If

    ' we need a transaction to modify the model
    Using trans As New Transaction(document, "Assign a driving dimension")
        trans.Start()

        ' we cannot assign a driving dimension to a global
        ' parameter that is already used to label other dimensions
        Dim dimset As ISet(Of ElementId) = gp.GetLabeledDimensions()
        For Each elemid As ElementId In dimset
            gp.UnlabelDimension(elemid)
        Next

        ' with the GP free of all previously labels (if there were any)
        gp.SetDrivingDimension(dimid)

        ' we should be able to commit, but we test the result anyway
        If trans.Commit() <> TransactionStatus.Committed Then
            Return False
        End If
    End Using

    Return True
End Function