' Paint any unpainted faces of a given wall
Public Sub PaintWallFaces(wall As Wall, matId As ElementId)
   Dim doc As Document = wall.Document
   Dim geometryElement As GeometryElement = wall.Geometry(New Options())
   For Each geometryObject As GeometryObject In geometryElement
      If TypeOf geometryObject Is Solid Then
         Dim solid As Solid = TryCast(geometryObject, Solid)
         For Each face As Face In solid.Faces
            If doc.IsPainted(wall.Id, face) = False Then
               doc.Paint(wall.Id, face, matId)
            End If
         Next
      End If
   Next
End Sub

Public Sub ApplyPaintByMaterial(document As Document, wall As Wall, material As Material)
    ' Before acquiring the geometry, make sure the detail level is set to 'Fine'
    Dim geoOptions As New Options()
    geoOptions.DetailLevel = ViewDetailLevel.Fine

    ' Obtain geometry for the given Wall element
    Dim geoElem As GeometryElement = wall.Geometry(geoOptions)

    ' Find a face on the wall
    Dim wallFace As Face = Nothing
    Dim geoObjectItor As IEnumerator(Of GeometryObject) = geoElem.GetEnumerator()
    While geoObjectItor.MoveNext()
        ' need to find a solid first
        Dim theSolid As Solid = TryCast(geoObjectItor.Current, Solid)
        If theSolid IsNot Nothing Then
            ' Examine faces of the solid to find one with at least
            ' one region. Then take the geometric face of that region.
            For Each face As Face In theSolid.Faces
                If face.HasRegions Then
                    wallFace = face.GetRegions()(0)
                    Exit For
                End If
            Next
        End If
    End While

    If wallFace Is Nothing Then
        TaskDialog.Show("Failure", "Could not find a face to paint on the given wall.")
        Return
    End If

    ' Paint material to the wall face (modification must be inside a transaction)


    Using transaction As New Transaction(document, "Painting a wall")
        transaction.Start()
        document.Paint(wall.Id, wallFace, material.Id)
        transaction.Commit()
    End Using

    ' For illustration purposes only, check if the painted material indeed got applied


    Dim isPainted As Boolean = document.IsPainted(wall.Id, wallFace)
    If isPainted Then
        Dim paintedMatId As ElementId = document.GetPaintedMaterial(wall.Id, wallFace)
        If paintedMatId = material.Id Then
            TaskDialog.Show("Painting material", "Wall painted successfully.")
        End If
    End If
End Sub