Public Sub ApplyPaintByMaterialParameter(document As Document, extrusion As Extrusion, material As Material)
    Dim geoFace As Face = Nothing

    Using transaction As New Transaction(document, "Painting")
        transaction.Start()

        ' create a new type and material parameter in the document.
        Dim famMgr As FamilyManager = document.FamilyManager
        If famMgr.Types.Size = 0 Then
            Dim createdType As FamilyType = famMgr.NewType("New_type")
            famMgr.CurrentType = createdType
        End If

    Dim materialParam As FamilyParameter = famMgr.AddParameter("Material_Para", GroupTypeId.Materials, SpecTypeId.Reference.Material, True)

    famMgr.[Set](materialParam, material.Id)

        ' Before acquiring the geometry, make sure the detail level is set to 'Fine'
        Dim geoOptions As New Options()
        geoOptions.DetailLevel = ViewDetailLevel.Fine

        ' Find the first geometry face of the given extrusion object
        Dim geoElem As GeometryElement = extrusion.Geometry(geoOptions)
        Dim geoObjectItor As IEnumerator(Of GeometryObject) = geoElem.GetEnumerator()
        While geoObjectItor.MoveNext()
            ' need to find a solid first
            Dim theSolid As Solid = TryCast(geoObjectItor.Current, Solid)
            If theSolid IsNot Nothing Then
                For Each face As Face In theSolid.Faces
                    geoFace = face
                    Exit For
                Next
            End If
        End While

        If geoFace Is Nothing Then
            TaskDialog.Show("Failure", "Could not find a face to paint.")
            transaction.RollBack()
            Return
        End If

        ' Paint a material family parameter to the extrusion face.
        document.Paint(extrusion.Id, geoFace, materialParam)
        transaction.Commit()
    End Using

    ' For illustration purposes only, check if the painted material indeed got applied


    Dim isPainted As Boolean = document.IsPainted(extrusion.Id, geoFace)
    If isPainted Then
        Dim paintedMatId As ElementId = document.GetPaintedMaterial(extrusion.Id, geoFace)
        If paintedMatId = material.Id Then
            TaskDialog.Show("Painting material", "Face painted successfully.")
        End If
    End If
End Sub